:: Set environment variables for I-X Process Panel
:: Austin Tate, AIAI, University of Edinburgh 13-Dec-2001
:: 1st parameter specifies I-X code base
:: 2nd parameter specifies Communications Strategy
::     "" or "xml" requires no special handling anything else uses plugins

if "%1"=="" goto NO-PARAM
set ix_base=%1
if not exist %ix_base%\scripts\win\ix-setvars.bat goto WRONG-LOCATION-IX
set ix_path=%ix_base%
:: If ix_base\ ix.jar exists use that as base, else use the ix_base directory
if exist %ix_base%\ix.jar set ix_path=%ix_base%\ix.jar
set ix_path=%ix_path%;%ix_base%\imports\xerces.jar
set ix_path=%ix_path%;%ix_base%\imports\jdom.jar

if "%2%"=="" (
   set comms_base=
   set comms_path=
   goto END-SETVARS
)
if "%2%"=="simple" (
   set comms_base=
   set comms_path=
   goto END-SETVARS
)
if "%2%"=="xml" (
   set comms_base=
   set comms_path=
   goto END-SETVARS
)

set comms_base=%ix_base%\comms\%2
call %comms_base%\scripts\win\comms-setvars.bat %comms_base%
goto END-SETVARS

:NO-PARAM
   echo ix-setvars.bat requires ix_base as a parameter
   pause
   goto END-SETVARS

:WRONG-LOCATION-IX
   echo Amend the batch script as this ix_base is wrong
   pause

:END-SETVARS